Составной ответ HTTP с использованием Perl или PHP

Question

Составной ответ HTTP с использованием Perl или PHP

Возможно ли предоставить HTTP-составной ответ (с использованием Perl/PHP) так же, как и составной запрос? Сценарий такой: я хотел бы указать URL-адрес, который принимает параметр для EmployeeID, а взамен ответ должен состоять из фотографии сотрудника, последней платежной ведомости и такой информации, как имя, возраст и адрес. Получающая сторона не является браузером, но это будет программа, которая получит этот ответ и обработает его позже. Есть идеи, как это сделать?

Чтобы предоставить дополнительную информацию на мой вышеприведенный вопрос я должен предоставить URL-адрес своему другу, который программно получит ответ. Например (в Perl):

$response = $ua->request($my_url)

Мое приложение должно отвечать не только данными, но и файлами! Меня попросили сделать это, чтобы вернуть составной ответ.

Я не знал, как начать с самого кодирования. Поиск в Google по "составному ответу" не вернул страницы, с которыми я мог бы ознакомиться и начать работу. Однако комментарий чансена был действительно полезно, а также его пример кода https://gist.github.com/1391017 . Большое спасибо.

8

php http perl response multipart

Author: slm, 2011-11-23

Source

1 answers

score 8 · Accepted Answer

Я представляю свой оригинал https://gist.github.com/1391017 в качестве ответа.

#!/usr/bin/perl
use strict;
use warnings;

use HTTP::Response;

my $response = HTTP::Response->new(
    200, 'OK', [ 'Content-Type' => 'multipart/form-data' ]
);

$response->protocol('HTTP/1.1');
$response->date(time);
$response->server('Foo/1.0');

my $name = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="name"',
], 'John Doe');

$response->add_part($name);

my $note = HTTP::Message->new([
    'Content-Type'        => 'text/plain; charset=UTF-8',
    'Content-Disposition' => 'form-data; name="note"',
], <<'NOTE');
Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616
NOTE

$response->add_part($note);

my $blob = HTTP::Message->new([
    'Content-Type'        => 'application/octet-stream',
    'Content-Disposition' => 'form-data; name="blob"; filename="blob.bin"',
]);
$blob->add_content('a chunk');
$blob->add_content(' of data');

$response->add_part($blob);

print $response->as_string;

Вывод:

HTTP/1.1 200 OK
Date: Thu, 24 Nov 2011 10:03:25 GMT
Server: Foo/1.0
Content-Type: multipart/form-data; boundary=xYzZY

--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="name"

John Doe
--xYzZY
Content-Type: text/plain; charset=UTF-8
Content-Disposition: form-data; name="note"

Resources:
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Message.pm
  o http://search.cpan.org/dist/HTTP-Message/lib/HTTP/Response.pm
  o http://tools.ietf.org/html/rfc2388
  o http://tools.ietf.org/html/rfc2616

--xYzZY
Content-Type: application/octet-stream
Content-Disposition: form-data; name="blob"; filename="blob.bin"

a chunk of data
--xYzZY--